Outlook 2010 da başlıksız eposta gönderiminde çıkan bilgilendirme penceresinin kapatılması.

Posted: 04 Nisan 2011 in OFFICE

Outlook 2010 uygulamasında başlıksız eposta gönderiminde çıkan Gönderme / Her Durumda Gönder bilgilendirme penceresinin kapatılması.

Outlook 2010 uygulamasında başlıksız bir eposta gönderilmek istendiğinde Outlook tarafından eposta göndericisine bir bilgilendirme penceresi gösterilir.
Bu ileti öğesini konu olmadan mı göndermek istiyorsunuz” şeklindeki uyarıda Gönderme / Her Durumda Gönder seçenekleri bulunmaktadır.

 

Önceki outlook sürümlerinde son kullanıcılar tarafından alınan geri bildirimlerden yola çıkan Microsoft çalışanları Office 2010 yazılımdaki outlook uygulamasında,
hem spam saldırılarına karşı başlıksız eposta kontrolünü sağlamak amacıyla hemde eposta göndericisine bir uyarı olması anlamında bu yeni özelliği kazandırmışlardır.

Eğer siz işiniz gereği başlıksız eposta gönderiyorsanız ve bu uyarının sürekli olarak karşınıza çıkmasını istemiyorsanız küçük macro yardımı ile bu uyarıyı devre dışı bırakabilirsiniz.

Outlook 2010 da başlıksız eposta gönderildiğinde Gönderme yada Her Durumda Gönder seçeneğinin bulunduğu uyarı penceresini devre dışı bırakmak için uygun çözüm adımı.

Çözüm adımı => Aşağıda girilen macro değerlerini kopyalayınız.

{SPIC}

Option Explicit

'=========================================================================
' Prevents Outlook® 2010 to display a no-subject warning message
' (c) Peter Marchert - http://www.outlook-stuff.com
' 2010-07-15 Version 1.0.0
' 2010-07-19 Version 1.0.1
'=========================================================================

Private WithEvents colInspectors As Outlook.Inspectors

Private Sub Application_Startup()

    '---------------------------------------------------------------------
    ' Set a reference to all forms
    '---------------------------------------------------------------------
    Set colInspectors = Outlook.Inspectors

End Sub

Private Sub colInspectors_NewInspector(ByVal Inspector As Inspector)

    '---------------------------------------------------------------------
    ' This code is running if a form (e. g. an e-mail) will be opened
    '---------------------------------------------------------------------

    Dim objItem As Object

    '---------------------------------------------------------------------
    ' Skip errors
    '---------------------------------------------------------------------
    On Error GoTo ExitProc

    '---------------------------------------------------------------------
    ' Set a reference to the open item
    '---------------------------------------------------------------------
    Set objItem = Inspector.CurrentItem

    '---------------------------------------------------------------------
    ' A new item does not have a received time
    '---------------------------------------------------------------------
    If Year(objItem.ReceivedTime) = 4501 Then

        '-----------------------------------------------------------------
        ' Check if the subject is empty if an e-mail was created by a
        ' template with predefined subject.
        '-----------------------------------------------------------------
        If objItem.Subject = "" Then objItem.Subject = " "

    End If

ExitProc:

    '---------------------------------------------------------------------
    ' Delete the reference to the form and to the item
    '---------------------------------------------------------------------
    Set objItem = Nothing
    Set Inspector = Nothing

End Sub

Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)

    On Error Resume Next

    '---------------------------------------------------------------------
    ' If the blank still exists it will now be removed (Outlook®
    ' will this not recognize)
    '---------------------------------------------------------------------
    Item.Subject = Trim(Item.Subject)

End Sub

Private Sub Application_Quit()

    '---------------------------------------------------------------------
    ' Delete the reference to the forms
    '---------------------------------------------------------------------
    Set colInspectors = Nothing

End Sub

{/SPIC}

Outlook uygulaması üzerinde => Alt + F11 fonksiyonunu kullanarak Microsoft Visual Basic for Applications penceresini açınız.
Sol menu de bulunan ThisOutlookSession link’ine iki kere tıklayınız ve açılan pencereye kopyaladığınız kodları yapıştırınız.

Kaydet butonuna (simge, kısayol )  tıklayarak  Microsoft Visual Basic for Applications penceresini kapatınız.
Outlook üzerinden File => Options => Trust Center => Trust Center Settings => Macro Settings => Enable all macros seçili olmalıdır.
Add-ins başlığı altında => Apply macro security settings to installed add-ins seçili olmalıdır.

Gerekli yapılandırmayı yukarıda belirtilen adımlarda uyguladıktan sonra outlook uygulamasını kapatarak, yeniden başlatınız.

Bu yapılandırmayı gerçekleştirdikten sonra Outlook üzerinden başlıksız eposta gönderiminizde bilgilendirme penceresi açılmayacaktır.

Bir Cevap Yazın

Aşağıya bilgilerinizi girin veya oturum açmak için bir simgeye tıklayın:

WordPress.com Logosu

WordPress.com hesabınızı kullanarak yorum yapıyorsunuz. Log Out / Değiştir )

Twitter resmi

Twitter hesabınızı kullanarak yorum yapıyorsunuz. Log Out / Değiştir )

Facebook fotoğrafı

Facebook hesabınızı kullanarak yorum yapıyorsunuz. Log Out / Değiştir )

Google+ fotoğrafı

Google+ hesabınızı kullanarak yorum yapıyorsunuz. Log Out / Değiştir )

Connecting to %s